Problem 4.52 with added parts:
Determine Sy and Sz and show that the commutation relations work for these as given in Eq. 4.134 page 171
Determne the S^2 operator
Determine the eigenvalues and eigenvectors of Sx, Sy, and Sz
Show one of the eigenvectors of Sx is indeed an eigenvector by operating Sx on that eigenvector.

Spinors for a particle with spin 3/2
m=3/2, 1/2, -1/2, -3/2

The notation is Sp32 is for m=+3/2
 and Sm32 is for m=-3/2

(%i1) Sp32:matrix(
 [1],
 [0],
 [0],
 [0]
);

Result

(%i2) Sp12:matrix(
 [0],
 [1],
 [0],
 [0]
);

Result

(%i3) Sm12:matrix(
 [0],
 [0],
 [1],
 [0]
);

Result

(%i4) Sm32:matrix(
 [0],
 [0],
 [0],
 [1]
);

Result

Ladder operators for a spin 3/2 particle

(%i5) Splus:matrix(
 [0,sqrt(3)*hbar,0,0],
 [0,0,2*hbar,0],
 [0,0,0,hbar*sqrt(3)],
 [0,0,0,0]
);

Result

(%i6) Sminus: matrix(
 [0,0,0,0],
 [sqrt(3)*hbar,0,0,0],
 [0,2*hbar,0,0],
 [0,0,sqrt(3)*hbar,0]
);

Result

Tests to see if the ladder operators produce the correct results:

(%i7) test1:Splus.Sp32;

Result

(%i8) test1:Splus.Sp12;

Result

(%i9) test1:Splus.Sm12;

Result

(%i10) test1:Splus.Sm32;

Result

(%i11) test1:Sminus.Sp32;

Result

(%i12) test1:Sminus.Sp12;

Result

(%i13) test1:Sminus.Sm12;

Result

(%i14) test1:Sminus.Sm32;

Result

The operator for Sx for a spin 3/2 particle

(%i15) Sx:(Splus+Sminus)/2;

Result

Eigenvalues for the Sx operator for a spin 3/2 particle

(%i16) eigenvalues(Sx);

Result

Notice that the output of function eigenvalues consists of two lists. The first list is the list of eigenvalues, and the second list is
the multiplicity of those values. In this example, there are 4 eigenvalues and none repeat.

(%i17) charpoly(Sx, %lambda),expand;

Result

(%i18) Sy:(Splus-Sminus)/(2*%i);

Result

(%i19) eigenvalues(Sy);

Result

(%i20) Sz: matrix(
 [3*hbar/2,0,0,0],
 [0,hbar/2,0,0],
 [0,0,-hbar/2,0],
 [0,0,0,-3*hbar/2]
);

Result

(%i21) eigenvalues(Sz);

Result

Testing the commutation relations found on page 171
[Sx,Sy]=i hbar Sz,
[Sy,Sz]=i hbar Sx, and
[Sz,Sx]=i hbar Sy

(%i22) (Sx.Sy-Sy.Sx)/%i/hbar;

Result

Note: The above is Sz as demonstrated below.

(%i23) %o22-Sz;

Result

(%i24) (Sy.Sz-Sz.Sy)/%i/hbar;

Result

(%i25) ratsimp(%);

Result

Note: The above is Sx as demonstated below.

(%i26) %o25-Sx;

Result

(%i27) (Sz.Sx-Sx.Sz)/%i/hbar;

Result

(%i28) ratsimp(%);

Result

Note: The above is Sy as demonstrated below.

(%i29) %o28-Sy;

Result

The square of the spin operator is given below and it is clear that this will give 3/2 *(3/2+1) hbar^2 for all eigenstates

(%i30) S2:Sx.Sx+Sy.Sy+Sz.Sz;

Result

Observe how simple the eigenvectors are for S^2 and for Sz

(%i31) eigenvectors(%);

Result

(%i32) eigenvectors(Sz);

Result

(%i33) eigenvectors(Sx);

Result

(%i34) eigenvectors(Sy);

Result

Below is an eigenvector of Sx with the eigenvalue of -3 hbar/2

(%i35) Evx: matrix(
 [1],
 [-sqrt(3)],
 [sqrt(3)],
 [-1]
);

Result

The next line demonstrates that Evx indeed is an eigenvector of Sx by operating on Evx with Sx and dividing by the eigenvalue
to get back the eigenvector Evx

(%i36) Sx.Evx/(-3*hbar/2);

Result


Created with wxMaxima.